8.4－ページで作業する

In this topic

ページに関連したアクティビティの詳細については、次のサブトピックを参照してください。：

• ページを作成する
• ページをアクティブ化する
• ページを並び替える
• ページの大きさを変更する
• ページを変更する
• ページを削除する

Creating pages

ページを作成するためのメソッドは、Documentクラスに属しています。

Document.AddPagesメソッドとDocument.AddPagesExメソッドは、どちらも、指定した数のページを文書の末尾に追加します。これらのメソッドの違いは、AddPagesExが、指定された大きさを使用する一方で、AddPagesが、デフォルト・ページの大きさを使用するということです。

同様に、Document.InsertPagesメソッドとDocument.InsertPagesExメソッドは、文書で指定された場所に、指定したページ数を挿入します。これらのメソッドの違いは、InsertPagesExが、指定された大きさを使用する一方で、InsertPagesが、デフォルトのページの大きさを使用するということです。

例として、次のVBAコードは、AddPagesメソッドを使用して、文書の末尾に3つのデフォルトの大きさのページを追加します。：

Public Function AddSomeSimplePages() as Page

    Set AddSomeSimplePages = ActiveDocument.AddPages(3)

End Function

次のVBAの例では、AddPagesExメソッドを使用して、文書の末尾に、幅8.5インチ×高さ11インチの3ページを追加します。：

Public Function AddSomeSpecifiedPages() as Page

    Dim doc as Document

    Set doc = ActiveDocument
    
    doc.Unit = cdrInch

    Set AddSomeSpecifiedPages = doc.AddPagesEx(3, 8.5, 11)

End Function

上記の例は、追加された最初のページを返します。;他のすべての追加ページは、このページに従います。したがって、返されたページのIndexプロパティをインクリメントすることで、追加されたページを参照できます。：

Dim firstNewPage As Page, secondNewPage As Page

Set firstNewPage = AddSomeSimplePages

Set secondNewPage = ActiveDocument.Pages(firstNewPage.Index + 1)

必要に応じて、あなたは、ページを作成することで、発生するイベントに応答するイベント・ハンドラを使用することができます。：

• Document.PageCreate

Activating pages

それぞれのページは、それが表示される文書のDocument.Pagesコレクションのメンバーです。Document.Pagesコレクションのページは、その文書に表示される順序で表示されます。たとえば、アクティブ文書の5ページ目は、ActiveDocument.Pages.Item(5)です。ページを追加、並び替え、削除される場合、影響を受けたページ・コレクションは、その文書の新しいページ順序を反映するために、すぐに更新されます。

あなたは、Application.ActivePageプロパティ（またはActiveDocument.ActivePage、または単にActivePage）を使用して、アクティブ文書のアクティブページにアクセスできます。Page型のアクティブ文書内のアクティブ・ページへの参照が返されます。

Dim pg As Page

Set pg = ActivePage

その文書のActivePageプロパティを使用して、その文書が、アクティブかどうかに関係なく、あなたは、文書のアクティブページにアクセスすることができます。：

Public Function getDocsActivePage(doc As Document) As Page

    Set getDocsActivePage = doc.ActivePage

End Function

あなたは、目的のページを見つけて、ページを切り替えることができます。続いて、そのActivateメソッドを呼び出します。次のVBAコードは、文書の3ページをアクティブにします。：

ActiveDocument.Pages(3).Activate

必要に応じて、あなたは、ページを起動することで、発生するイベントに応答するイベント・ハンドラを使用することができます。：

• Document.PageActivate

あなたは、ページのアクティブ化を解除すると発生するイベントに応答するイベント・ハンドラを使用することもできます。：

• Document.PageChange

Reordering pages

ページをMoveToメソッドを使用して、文書内の別の場所に移動できます。次のVBAコードは、2ページを4ページの位置へ移動します。：

ActiveDocument.Pages(2).MoveTo 4

アクティブではない文書におけるページをアクティブ化することは、その文書をアクティブ化しません。文書をアクティブにするために、あなたは、そのActivateメソッドを使用する必要があります。（「文書をアクティブ化する」を参照）。

Sizing pages

あなたは、デフォルト・ページの大きさを指定して、ページの大きさと向きを指定し、定義されたページの大きさを使用することができます。

ページの大きさと向きを指定する

ActiveDocument.Unit = cdrMillimeter

ActivePage.SetSize 210, 297

ActivePage.Orientation = cdrLandscape

デフォルト・ページの大きさを指定する

Dim doc As Document

Set doc = ActiveDocument

doc.Unit = cdrMillimeter

doc.Pages(0).SetSize 297, 210

Dim doc As Document

Set doc = ActiveDocument

doc.Unit = cdrMillimeter

doc.MasterPage.SetSize 297, 210

定義されたページの大きさを使用する

Dim pageSizeName As String

pageSizeName = Application.PageSizes(3).Name

Dim thisSize As PageSize

Set thisSize = Application.PageSizes("Business Card")

Dim pageWidth As Double, pageHeight As Double

Application.Unit = cdrMillimeter

pageWidth = Application.PageSizes(3).Width

pageHeight = Application.PageSizes(3).Height

Public Sub deletePageSize(thisSize As PageSize)

    If Not thisSize.BuiltIn Then thisSize.Delete

End Sub

Modifying pages

あなたは、アクティブかどうかに関係なく、ページを変更することができます。

アクティブではない文書におけるページをアクティブ化することは、その文書をアクティブ化しません。文書をアクティブにするために、あなたは、そのActivateメソッドを使用する必要があります。（「文書をアクティブ化する」を参照）。

あなたが修正したいページを明示的に参照することによって、あなたは、ページをアクティブ化することなく、それらの変更を行うことができます。次のVBAコードは、ページをアクティブ化することなく、アクティブ文書の3ページにある、すべてのshapeを削除します。：

Public Sub DeleteShapesFromPage3()

    Dim doc As Document

    Set doc = ActiveDocument

    doc.Pages(3).Shapes.All.Delete

End Sub

Deleting pages

あなたは、次のVBAの例のように、Deleteメソッドを使用して、ページを削除することができます。：

ActivePage.Delete

Page.Deleteメソッドは、そのページから、すべてのshapeを削除し、その文書のPagesコレクションからページを削除します。続いて、変更を反映するために、そのコレクションを更新します。

あなたが、１つ以上のページを削除したい場合、あなたは、不必要なページごとに、Deleteメソッドを使用する必要があります。しかしながら、あなたは、文書内のすべてのページを削除することはできません。あなたは、以下のVBAコードを使用することにより、文書内に残った最後のページを削除しようとするのを避けることができます。：

If ActiveDocument.Pages.Count > 1 Then ActivePage.Delete

必要に応じて、あなたは、ページを削除することによって、発生するイベントに応答するイベント・ハンドラを使用することができます。：

• Document.PageDelete