Automationブリッジ

Requirements

Automation技術は、Windowsのプラットホーム上のOpenOffice.orgでのみ使用することができます。（Windows 95, 98, NT4, ME, 2000, XP）。Macintosh OSとUNIXには、COM実装がありますが、これらのプラットフォーム上で、Automationをサポートするための努力はなされていません。

Automationを使用することは、すなわち、VBのCreateObject()のような関数やCのCoCreateInstance()を使用して、COMのようなスタイルでオブジェクトを作成することが含まれています。これは、Windowsシステム・レジストリに登録されるOpenOffice.orgオートメーション・オブジェクトを必要とします。この登録は、オフィスが、システムにインストールされるたびに実行されます。登録が行われなかった場合、例えば、バイナリは、特定の場所にコピーされるため、続いて、Automationクライアントは、正しく動作しないか、まったく動作しません。詳細については、「Service Managerコンポーネント」を参照してください。

A Quick Tour

次の例は、Automationによって、OpenOffice.orgの機能にアクセスする方法を示しています。インライン・コメントに注目して下さい。唯一のオートメーション固有の呼び出しは、最初の行のWScript.CreateObject()です。残りは、OpenOffice.org APIの呼び出しです。ヘルパー関数createStruct()とinsertIntoCell()は、リストの最後に表示されます。

  'This is a VBScript example
  'The service manager is always the starting point
  'If there is no office running then an office is started up
  ' これは、VBScriptの例です。サービス管理プログラムは、常に開始位置です。オフィスがない場合、オフィスが起動します。
  Set objServiceManager= WScript.CreateObject("com.sun.star.ServiceManager")
 
  'Create the CoreReflection service that is later used to create structs
  ' 後で、構造体を作成するために使用されるCoreReflectionサービスを作成します。
  Set objCoreReflection= objServiceManager.createInstance("com.sun.star.reflection.CoreReflection")
 
  'Create the Desktop
  '  デスクトップを作成します。
  Set objDesktop= objServiceManager.createInstance("com.sun.star.frame.Desktop")
 
  'Open a new empty writer document
  ' 新しい空のWriter文書を開きます。
  Dim args()
  Set objDocument= objDesktop.loadComponentFromURL("private:factory/swriter", "_blank", 0, args)
 
  'Create a text object
  ' テキスト・オブジェクトを作成します。
  Set objText= objDocument.getText
 
  'Create a cursor object
  ' カーソル・オブジェクトを作成します。
  Set objCursor= objText.createTextCursor
 
  'Inserting some Text
  ' いくつかのテキストを挿入します。
  ' The first line in the newly created text document.
  objText.insertString objCursor, "新たに作成されたテキスト文書の最初の行。" & vbLf, false
 
  'Inserting a second line
  ' ２つ目の行を挿入します。
  ' Now we're in the second line
  objText.insertString objCursor, "現在、私たちは、2つ目の行にいます", false
 
  'Create instance of a text table with 4 columns and 4 rows
  ' 4列4行のテキスト表のインスタンスを作成する
  Set objTable= objDocument.createInstance( "com.sun.star.text.TextTable")
  objTable.initialize 4, 4
 
  'Insert the table
  ' 表を挿入します
  objText.insertTextContent objCursor, objTable, false
 
  'Get first row
  ' 最初の行を取得します
  Set objRows= objTable.getRows
  Set objRow= objRows.getByIndex( 0)
 
  'Set the table background color
  ' 表の背景色を設定します
  objTable.setPropertyValue "BackTransparent", false
  objTable.setPropertyValue "BackColor", 13421823
 
  'Set a different background color for the first row
  ' 最初の行に、異なる背景色を設定する
  objRow.setPropertyValue "BackTransparent", false
  objRow.setPropertyValue "BackColor", 6710932
 
  'Fill the first table row
  ' 最初の表の行を塗りつぶす
  insertIntoCell "A1","FirstColumn", objTable 'insertIntoCell is a helper function, see below
					 	    ' insertIntoCellは、ヘルパー関数（下記参照）です
  insertIntoCell "B1","SecondColumn", objTable
  insertIntoCell "C1","ThirdColumn", objTable
  insertIntoCell "D1","SUM", objTable
 
  objTable.getCellByName("A2").setValue 22.5
  objTable.getCellByName("B2").setValue 5615.3
  objTable.getCellByName("C2").setValue -2315.7
  objTable.getCellByName("D2").setFormula"sum "
 
  objTable.getCellByName("A3").setValue 21.5
  objTable.getCellByName("B3").setValue 615.3
  objTable.getCellByName("C3").setValue -315.7
  objTable.getCellByName("D3").setFormula "sum "
 
  objTable.getCellByName("A4").setValue 121.5
  objTable.getCellByName("B4").setValue -615.3
  objTable.getCellByName("C4").setValue 415.7
  objTable.getCellByName("D4").setFormula "sum "
 
  'Change the CharColor and add a Shadow
  ' CharColorを変更して、Shadowを追加します
  objCursor.setPropertyValue "CharColor", 255
  objCursor.setPropertyValue "CharShadowed", true
 
  'Create a paragraph break
  ' 段落区切りを作成する
  'The second argument is a com::sun::star::text::ControlCharacter::PARAGRAPH_BREAK constant
  ' 2つ目の引数は、com::sun::star::text::ControlCharacter::PARAGRAPH_BREAK定数です。
  objText.insertControlCharacter objCursor, 0 , false
 
  'Inserting colored Text.
  ' 色のついたテキストを挿入する。
  ' This is a colored Text - blue with shadow
  objText.insertString objCursor, " これは、影のついた青色のテキストです" & vbLf, false
 
  'Create a paragraph break ( ControlCharacter::PARAGRAPH_BREAK).
  ' 段落区切りを作成します（ControlCharacter：PARAGRAPH_BREAK）。
  objText.insertControlCharacter objCursor, 0, false 
 
  'Create a TextFrame.
  ' TextFrameを作成します。
  Set objTextFrame= objDocument.createInstance("com.sun.star.text.TextFrame")
 
  'Create a Size struct.
  ' Size構造体を作成します。
  Set objSize= createStruct("com.sun.star.awt.Size") 'helper function, see below
							  ' ヘルパー関数、下記参照
  objSize.Width= 15000
  objSize.Height= 400
  objTextFrame.setSize( objSize)
 
  ' TextContentAnchorType.AS_CHARACTER = 1
  objTextFrame.setPropertyValue "AnchorType", 1
 
  'insert the frame
  ' フレームを挿入します
  objText.insertTextContent objCursor, objTextFrame, false
 
  'Get the text object of the frame
  ' フレームのテキスト・オブジェクトを取得します。
  Set objFrameText= objTextFrame.getText
 
  'Create a cursor object
  ' カーソル・オブジェクトを作成します。
  Set objFrameTextCursor= objFrameText.createTextCursor
 
  'Inserting some Text
  ' いくつかのテキストを挿入します。
  ' The first line in the newly created text frame.
  objFrameText.insertString objFrameTextCursor, "新しく作成されたテキスト・フレームの最初の行。", _
  false
  ' With this second line the height of the frame raises.
  objFrameText.insertString objFrameTextCursor, _
  vbLf & "この２つ目の行で、フレームの高さを上げます。", false 
 
  'Create a paragraph break
  ' 段落区切りを作成する
  'The second argument is a com::sun::star::text::ControlCharacter::PARAGRAPH_BREAK constant
  ' 2つ目の引数は、com::sun::star::text::ControlCharacter::PARAGRAPH_BREAK定数です。
  objFrameText.insertControlCharacter objCursor, 0 , false
 
  'Change the CharColor and add a Shadow
  ' CharColorを変更して、Shadowを追加します
  objCursor.setPropertyValue "CharColor", 65536
  objCursor.setPropertyValue "CharShadowed", false
 
  'Insert another string
  ' 他の文字列を挿入する
  ' That's all for now !!
  objText.insertString objCursor, " それは、今のところすべてです ！！", false
 
  On Error Resume Next
      If Err Then
      '  An error occurred
　　　MsgBox "エラーが発生"
  End If
 
 
  Sub insertIntoCell( strCellName, strText, objTable) 
      Set objCellText= objTable.getCellByName( strCellName)
      Set objCellCursor= objCellText.createTextCursor
      objCellCursor.setPropertyValue "CharColor",16777215
      objCellText.insertString objCellCursor, strText, false
  End Sub
 
  Function createStruct( strTypeName)
      Set classSize= objCoreReflection.forName( strTypeName)
      Dim aStruct
      classSize.createObject aStruct
      Set createStruct= aStruct
  End Function

このスクリプトは、新しい文書を作成し、必要に応じてオフィスを開始しました。また、スクリプトは、テキストを記述して、表を作成し埋め込み、異なる背景とペンの色を使用しました。オブジェクトは、com.sun.star.ServiceManagerと呼ばれるActiveXコンポーネントとして、１つだけ作成されます。サービス・マネージャは、続いて、他のオブジェクトを順番に提供する追加のオブジェクトを作成するために使用されます。それらのオブジェクトのすべては、機能を提供します。それは、適切な関数とプロパティを呼び出すことによって、使用することができます。開発者は、どのオブジェクトが、望む機能を提供するか、そして、どのように取得するか学ぶ必要があります。「はじめのステップ」のChapterでは、主にプログラマーに利用可能なOpenOffice.orgオブジェクトを紹介します。